球面調和関数

• 媒介変数表示
• 球面調和関数
• 種々の量子数
• 変形した原子核 [ver.4]

変形した原子核 (Legendre展開)

[ver.4] ONLY !

球面調和関数 Y[lm](θ,φ) で，特にm=0の場合は，通常のLegendre関数 P[l](cos(θ)) の定数倍となり，これはφに依存しない実関数です．幾つ かの l に対するY[l](θ)を示します．

変形した原子核の形状は，このY[l](θ)の偶数の(l=λ)の項を用いて次のように 展開する事ができます．

ここでβは変形の度合を表すパラメータです．β=0なら球形となります．こ の式で表される3 次元形状をgnuplotで表示してみます．前節でと同様，空間座標(x,y,z)を角度 u,vと動径rを用いて表します．

   x = R(theta)*cos(u)*cos(v)
   y = R(theta)*sin(u)*cos(v)
   z = R(theta)*sin(v)

ここでθ(=theta)はZ軸から計った動径の角度なので，θ=π/2-v でvと 関係づけられます．パラメータでこの曲面を表現するには，uとvを0から360 まで変化させます．以下の例ではβ2=0.3, β4=0.1の場合を示しています．また R0=1としています．

gnuplot> set parametric

        dummy variable is t for curves, u/v for surfaces
gnuplot> set angle degree
gnuplot> set urange [0:360]
gnuplot> set vrange [0:360]
gnuplot> set isosample 16,16
gnuplot> set ticslevel 0
gnuplot> set view 75,25
gnuplot> set size 0.7,1.0
gnuplot> set xrange [-2:2]
gnuplot> set yrange [-2:2]
gnuplot> set zrange [-2:2]
gnuplot> set urange [0:360]
gnuplot> set vrange [0:360]
gnuplot> y0(t)=1.0
gnuplot> y2(t)=sqrt(5.0/(4*pi))*( 3.0*cos(t)**2 -  1.0             )/2.0
gnuplot> y4(t)=sqrt(9.0/(4*pi))*(35.0*cos(t)**4 - 30*cos(t)**2 +3.0)/8.0
gnuplot> b2=0.3
gnuplot> b4=0.1
gnuplot> r(t) = 1 + b2*y2(0.5*pi-t) + b4*y4(0.5*pi-t)
gnuplot> fx(u,v)=cos(u)*cos(v)
gnuplot> fy(u,v)=sin(u)*cos(v)
gnuplot> fz(v)=sin(v)
gnuplot> set pm3d
gnuplot> splot r(v)*fx(u,v),r(v)*fy(u,v),r(v)*fz(v) with lines

β2とβ4の値は正負を取る事ができます．β2=-0.4 と 0.4 に対して，β4 を -0.2 から 0.2 まで変化させて原子核の形状を表示してみます．β2>0 の場合，原子核は縦に長い回転楕円体となり，プロレート型と呼ばれます． β2<0では偏平な形で，オブレート型と呼ばれます．

gnuplot> set border 0
gnuplot> unset xtics
gnuplot> unset ytics
gnuplot> unset ztics
gnuplot> unset colorbox
gnuplot> b2 = -0.4 ; b4 = -0.2 ; replot ; pause -1
gnuplot> b2 = -0.4 ; b4 =  0.0 ; replot ; pause -1
gnuplot> b2 = -0.4 ; b4 =  0.2 ; replot ; pause -1
gnuplot> b2 =  0.4 ; b4 = -0.2 ; replot ; pause -1
gnuplot> b2 =  0.4 ; b4 =  0.0 ; replot ; pause -1
gnuplot> b2 =  0.4 ; b4 =  0.2 ; replot ; pause -1

	β4 = -0.2	β4 = 0	β4 = 0.2
β2 = -0.4
β2 = 0.4